How to apply mapcar to a function with multiple arguments

Question

I have packages variables that have list of github users and package names.

(defvar packages '('("auto-complete" . "auto-complete")
                   ("defunkt" . "markdown-mode")))

I want to git clone if the file is not exist yet.

(defun git-clone (author name)
  (let* ((repo-url (concat "git@github.com:" author "/" name ".git")))
    (print repo-url)
    (unless (file-exists-p (concat "~/.emacs.d/git/" name))
      (shell-command (concat "git clone " repo-url " ~/.emacs.d/git/" name)))))

And I want to apply git-clone to all packages variable to packages list. But I could not figure out how to apply with arguments.

; This obviously doesn't work
(mapcar `git-clone `packages)

By the way, you have an extra `'` in your `defvar` declaration. — Dan, Dec 13 '15 at 13:57
FWIW, this has got to be a duplicate, but I don't have time to search for it. ;-) — Drew, Dec 13 '15 at 17:44

Dan · Accepted Answer · 2015-12-13T14:30:30.483

9

You can create an anonymous lambda function to take each element of your list and apply your function to it.

Example:

(defvar packages '(("auto-complete" . "auto-complete")
                   ("defunkt" . "markdown-mode")))

(defun toy-fnx (author name)
  "Just testing."
  (message "Package %s by author %s" name author)
  (sit-for 1))

(mapcar (lambda (package)
          (funcall #'toy-fnx (car package) (cdr package)))
        packages)

Note that, if you don't care about the return values (ie, your function is only for side effects, which appears to be the case here), you can use mapc in place of mapcar:

(mapc (lambda (package)
        (funcall #'toy-fnx (car package) (cdr package)))
      packages)

For your specific purposes, a loop may be simplest:

(cl-dolist (package packages)      ; or dolist if you don't want to use cl-lib
  (funcall #'toy-fnx (car package) (cdr package)))

edited Dec 13 '15 at 14:30

answered Dec 13 '15 at 13:57

Dan

32,584
6
98
168

There's no advantage to `cl-dolist` over plain `dolist` here. – npostavs Dec 13 '15 at 14:09
@npostavs: edited. – Dan Dec 13 '15 at 14:30
Thanks! I totally forgot about `funcall`. – ironsand Dec 13 '15 at 15:00
3

Hmm, I skipped over the `funcall` before, but looking again it seems redundant, why not just call `toy-fnx` directly? – npostavs Dec 13 '15 at 15:24
@npostavs: correct. It was just a way to illustrate mapcar and friends. – Dan Dec 13 '15 at 16:26

Wilfred Hughes · Answer 2 · 2017-07-24T15:28:45.430

9

If you're happy using dash.el you can use -each and destructuring -let:

(require 'dash)

(--each packages
  (-let [(author . name) it]
    (git-clone author name)))

Alternatively, you can use -lambda from dash.el to create an anonymous function with destructuring:

(mapcar
 (-lambda ((author . name)) (git-clone author name))
 packages)

edited Jul 24 '17 at 15:28

answered Dec 13 '15 at 19:32

Wilfred Hughes

6,890
2
29
59

score 1 · Answer 3 · answered Jan 24 '20 at 14:43

Building on the answer by Dan, if you do this kind of thing often it may be useful to define a 'starred' variant of mapcar, as one does in e.g. Python:

(defun my-mapcar* (func arglist)
  (mapcar 
     (lambda (args)
       (apply func args))
     arglist))

so that e.g.

(my-mapcar* #'+ '((1) (1 1) (1 1 1) (1 1 1 1))
      ⇒ (1 2 3 4)

How to apply mapcar to a function with multiple arguments

3 Answers3

Linked