Delete lines containing the pattern and the line before

Question

I'd like to delete two lines in a file, containing pattern aaa bbb ccc.

I have used the following expression, which deletes the line containing pattern aaa bbb ccc and the line before.

$ sed -n '/aaa bbb ccc/{s/.*//;x;d;};x;p;${x;p;}' file.txt | sed '/^$/d'

This works for one file. It doesn't work for multiple files

$ for i in *.txt; do sed -n '/aaa bbb ccc/{s/.*//;x;d;};x;p;${x;p;}' "$i" | sed '/^$/d'; done

example file:

xxx
yyy
aaa bbb ccc
eee
fff
aaa bbb ccc
ggg
hhh

result file:

xxx
eee
ggg
hhh

Answer 1

Looks like you're using gnu sed - in that case you can do something like

sed -s 'N;/PATTERN/!P;D' ./*.txt

With other seds you'd have to loop over the list of files

for file in ./*.txt
do
sed '$!N;/PATTERN/!P;D' "$file"
done

This will always keep two lines in the pattern space and print the first one if the pattern space doesn't match so with an input like

some line
PATTERN
PATTERN
more
lines
another line
PATTERN

it will print

more
lines