Change "\n" by "|" between 2 patterns (patterns excluded) with sed

Question

I'd like to change \n by | between 2 patterns (patterns excluded) with sed.

I have a file with an adress sequence several time :

Adress:
1540 Broadway
New York
NY 10036
United-states
###

I would like to get that :

Adress:1540 Broadway|New York|NY 10036|United-states
###

I use the following line code :

sed -i "/^Adress:/!b;:a;/###/bb;$!{N;ba};:b;s/\n/\|/g;tb" file.txt

...but it includes the two patterns and I get this wrong result :

Adress:|1540 Broadway|New York|NY 10036|United-states|###

How to change it to exclude patterns from the substitute?

Answer 1

Using a loop for this kind of job isn't recommended, unless you're dealing with a small no. of lines¹. You're better off using ranges and the hold space:

sed '/Address/,/###/{
/###/!H;/Address/h;/###/!d;x;s/\n//;s/\n/|/g;G
}' infile

That is, for each line in that range do the following: if it's not the last line in range append to hold space (overwriting if it's the first line in range) and delete the line, else exchange buffers, remove the first embedded newline and replace the remaining ones with |. Then append the hold buffer content to the pattern space.
This will fail if the last Address is not followed by ### so to avoid that, use a second condition and delete only if it's not the last line of input, otherwise append to hold buffer, exchange and quit:

sed '/Address/,/###/{
/###/!H;/Address/h;/###/!{
$!d;H;x;q
}
x;s/\n//;s/\n/|/g;G
}' infile

---

^{1: the more lines you have to pull in, the slower it gets, due to the need of constantly checking the pattern space for a match - see the results here (it's a different requirement, I know, but just to give you an idea...)}