How to compare two files line by line, to check how many of them have moved up or down?

Question

'File A' has list of university ranked in year let's say 2018, 'File B' has list of university ranked in year 2017,

File A (2018 Rankings):

University of Oxford
University of Cambridge
California Institute of Technology
Stanford University
Massachusetts Institute of Technology

File B (2017 Rankings):

University of Oxford
California Institute of Technology
Stanford University
University of Cambridge
Massachusetts Institute of Technology

'Stanford University' is ranked 4th in 2018, whereas it was 3rd in 2017. So, I want an output of files which contains only the university ranked in 2017, which went above Stanford in 2018 rankings, similarly, list of university which was ranked in 2017 which went below Stanford in 2018 rankings.

Expected output should contain two files having data on,

**Ranked above Stanford: **
University of Cambridge

**Ranked below Stanford: **
NONE

NONE - As no university was ranked above stanford in 2017 rankings went below standford in 2018 rankings.

I want to be able to do this for any university mentioned in the list.

Data entered here are snippets from huge data files, they contain 1000+ lists of university ranked. I want to analyze this for few university only.

Answer 1

Below answer after question clarified in correct way, here is the final solution for that:

awk -F'\n' -v RS='Stanford University' 
    'NR==1 && NR==FNR{for (i=1;i<NF;i++)above[$i]++;next}
     NR==2&&NR==FNR{for (j=2;j<NF;j++)below[$j]++;next} 
     NR==3{for (x=1;x<NF;x++)X2017[$x]++;next}
     NR==4{for (y=2;y<NF;y++)Y2017[$y]++;next} 
END{ for (Z in Y2017) {if (Z in above) print Z>"Ranked-above.txt" }; 
     for (T in X2017) {if (T in below) print T>"Ranked-below.txt" };
}' 2018  2017

The output would be two files Ranked-above.txt and Ranked-below.txt with expected result.

**Ranked-above.txt**
University of Cambridge

**Ranked-below.txt**

You can search for another Universities with specifying in RS='University NAME HERE'

Answer 2

This is not an answer to your question in the sense that it doesn't produce the output that you required. It does however produce a table of changes in ranks between the lines in the two files.

The following awk program will output the change in ranking between the two files like this:

$ awk -f script.awk rankings-2017.txt rankings-2018.txt
        University of Oxford
 +2     University of Cambridge
 -1     California Institute of Technology
 -1     Stanford University
NEW     Uppsala University
 -1     Massachusetts Institute of Technology

("Uppsala University" was added on the second to last row of the second file).

The script:

NR == FNR       { rank[++n] = $0 }
NR != FNR       { ++nn;
    for (i = 1; i <= n; ++i) {
        if (rank[i] == $0) {
            if (i == nn) {
                printf("   ");
            } else {
                printf("%+3d", i - nn);
            }
            printf("\t%s\n", $0);
            next;
        }
    }
    printf("NEW\t%s\n", $0);
}