Bash: How do I quote shell arguments with spaces inside a variable containing multiple arguments without using an array?

Question

In Bash, is it possible to pass a variable with a properly-quoted list of options to a command and not have it split on whitespace inside quotes? IOW, this script:

MYCONFIG="--hi FOO=bar 'X=ABC 123'"
printf '[%s]\n' $MYCONFIG

Outputs:

[--hi]
[FOO=bar]
['X=ABC]
[123']

What I would like it to instead output is

[--hi]
[FOO=bar]
['X=ABC 123']

I realize it can be done with arrays or as a function, but I'm working with a script that already depends on the creation of a string variable to hold args. It can't be replaced with a function because other users of the script will get errors.

Is it possible to construct a string with proper quotation to prevent breaking on spaces inside quoted strings?

Failing that, how can I modify the script to support both array configs and existing string configs, perhaps converting the one to the other?

Answer 1

In zsh, you'd do:

$ MYCONFIG="--hi FOO=bar 'X=ABC 123'"
$ printf '[%s]\n' ${(z)MYCONFIG}
[--hi]
[FOO=bar]
['X=ABC 123']

$ printf '[%s]\n' "${(Q@)${(z)MYCONFIG}}"
[--hi]
[FOO=bar]
[X=ABC 123]

Where the z parameter expansion flag breaks the input using shell tokenisation (note that it's according the zsh syntax, that z flag can also be tuned with the Z flag wrt comment or newline handling, see info zsh flags for details), and the Q peels one level of quoting.

In bash, you could always do:

readarray -td '' words < <(
  export MYCONFIG
  zsh -c 'print -rNC1 -- ${(z)MYCONFIG}'
)
printf '[%s]\n' "${words[@]}"

To get zsh to do that tokenisation and pass the words to bash NUL-delimited.

Adding the Q flag in that case could be problematic as if $MYCONFIG contains $'\0', that would add an extra NUL. In any case though, bash, contrary to zsh can't have NULs in the contents of its variables, so you might as well tell zsh to remove them:

readarray -td '' words < <(
  export MYCONFIG
  zsh -c '
    quoted_words=( ${(z)MYCONFIG} )
    unquoted_words=( "${(Q@)quoted_words}" )
    without_nul=( "${(@)unquoted_words//$'\''\0'\''}" )
    print -rNC1 -- "${without_nul}"
  '
)

Answer 2

With a little tweak (single quotes will have to be sacrificed):

xargs -n1 printf "[%s]\n" <<<"$MYCONFIG"
[--hi]
[FOO=bar]
[X=ABC 123]

The xargs utility is able to distinguish parameters with -n flag. Unfortunately, the -I flag does not allow splitting by unquoted blanks.